1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77

{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    nixery = {
      type = "github";
      owner = "tazjin";
      repo = "nixery";
      flake = false;
    };
  };
  outputs =
    {
      self,
      nixpkgs,
      nixery,
    }:
    let
      systems = [
        "x86_64-linux"
        "i686-linux"
        "x86_64-darwin"
        "aarch64-linux"
        "armv6l-linux"
        "armv7l-linux"
      ];
      forAllSystems = f: nixpkgs.lib.genAttrs systems f;
    in
    {
      overlays.default = import ./overlay.nix { inherit nixery; };
      nixosModules.nixery = import ./module.nix { inherit nixery; };
      nixosModules.default = self.nixosModules.nixery;
      packages = forAllSystems (
        system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
        in
        {
          default = (import nixery { inherit pkgs; }).nixery;
        }
      );
      checks = forAllSystems (
        system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
        in
        {
          vmTest = import ./test.nix {
            inherit pkgs;
            nixeryModule = self.nixosModules.default;
          };
        }
      );
      apps = forAllSystems (
        system:
        let
          pkgs = import nixpkgs {
            inherit system;
            overlays = [ self.overlays.default ];
          };
        in
        {
          default = {
            type = "app";
            program = "${pkgs.writeShellScript "serve-nixery" ''
              export PORT=''${1:-8080}
              export NIXERY_PKGS_PATH="${pkgs.path}";
              export NIXERY_STORAGE_BACKEND="filesystem";
              export NIX_TIMEOUT="60";
              export STORAGE_PATH=".nixery";
              export WEB_DIR="/dev/null";
              ${pkgs.lib.getExe' pkgs.nixery "server"}
            ''}";
          };
        }
      );
    };
}