1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89

export extern "ssh" [
    destination?: string@"nu-complete ssh-host"
    -4            # Forces ssh to use IPv4 addresses only.
    -6            # Forces ssh to use IPv6 addresses only.
    -A            # Enables forwarding of connections from an authentication agent such as ssh-agent(1).
    -a            # Disables forwarding of the authentication agent connection.
    -B: string    # bind_interface
    -b: string    # bind_address
    -C            # Requests compression of all data
    -c: string    # cipher_spec
    -D            # [bind_address:]port
    -E: string    # log_file
    -e            # escape_char
    -F: string    # configfile
    -f            # Requests ssh to go to background just before command execution.
    -G            # Causes ssh to print its configuration after evaluating Host and Match blocks and exit.
    -g            # Allows remote hosts to connect to local forwarded ports
    -I: string    # pkcs11
    -i: string@"nu-complete ssh-identity"    # identity_file
    -J: string    # destination
    -K            # Enables GSSAPI-based authentication and forwarding(delegation) of GSSAPI credentials to the server.
    -k            # Disables forwarding (delegation) of GSSAPI credentials to the server.
    -L: string    # [bind_address:]port:host:hostport / [bind_address:]port:remote_socket / local_socket:host:hostport / local_socket:remote_socket
    -l: string    # login_name
    -M            # Places the ssh client into “master” mode for connection sharing.
    -m: string    # mac_spec
    -N            # Do not execute a remote command.
    -n            # Redirects stdin from /dev/null (5) for details.
    -O: string    # ctl_cmd
    -o: string    # option
]

def parse-host [file: string] {
    let lines = $file | open | lines | str trim

    mut result = []
    for $line in $lines {
        let data = $line | parse --regex '^Include\s+(?<file>.+)'
        if ($data | is-not-empty) {
            let include = parse-host ($data.file | first)
            $result = ($result | append $include)
            continue
        }
        let data = $line | parse  --regex '^Host\s+(?<host>.+)'
        if ($data | is-not-empty) {
            let host = $data.host | first
            if ($host == '*') {
                continue
            }
            $result = ($result | append { 'value': $host, 'description': "" })
            continue;
        }
        let data = $line | parse --regex '^HostName\s+(?<hostname>.+)'
        if ($data | is-not-empty) {
            let last = $result | last | update 'description' ($data.hostname | first)
            $result = ($result | drop | append $last)
        }
    }
    $result
}

def "nu-complete ssh-host" [] {
    mut files = [
        '/etc/ssh/ssh_config',
        '~/.ssh/config'
    ] | filter { |file| $file | path exists }


    $files | each { |file|
        parse-host $file
    } | flatten
}

def "nu-complete ssh-identity" [] {
  ls ~/.ssh/
  | where {|f|
      ($f.name | path parse | get extension) == "pub"
    }
  | get name
  | path parse
  | each {|p| {'value': $'~/.ssh/($p.stem)', 'description': $p.stem} }
}

export def ssh-add-all [] {
    nu-complete ssh-identity
    | each {|s| print $s.value; ^ssh-add ($s.value | path expand); print '' }
    null
}